home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (PO)
/
Nibble Volume 12, No. 12 (1991-12)(MindCraft Publishing)(Side A).zip
/
Nibble Volume 12, No. 12 (1991-12)(MindCraft Publishing)(Side A).po
/
FINDQUOTE.S
< prev
next >
Wrap
Text File
|
1996-12-24
|
2KB
|
78 lines
REP40
* FINDQUOTE
* COPYRIGHT (C) 1982
* DIGIPAC COMPUTER CONSULTING
REP40
*
* APPLESOFT USEAGE
*
PRGSTRT EQU $67
LINPRT EQU $ED24
OUTSPC EQU $DB57
*
* STORAGE
*
STRLIN EQU $1A
FLAG EQU $1C
LINNUM EQU $1D
*
ORG $300
*
LDA PRGSTRT ; FIND THE BEGINNING OF THE PROGRAM
STA STRLIN
LDA PRGSTRT+1
STA STRLIN+1
NEWLIN LDA #0 ; SET THE FLAG
STA FLAG
LDY #$2 ; FIND AND STORE THE LINE NUMBER
LDA (STRLIN),Y
STA LINNUM
INY
LDA (STRLIN),Y
STA LINNUM+1
SRCHLN INY
LDA (STRLIN),Y
CMP #0 ;SEARCH FOR CARRIAGE RETURN
BEQ CHKFLG
CMP #$22 ; SEARCH FOR QUOTE
BEQ SETFLG
JMP SRCHLN
CHKFLG LDA FLAG
CMP #1 ; IF FLAG SET THEN
BEQ ERROR ; PRINT LINE NUMBER
JMP EXIT ; ELSE POSSIBLE EXIT
SETFLG LDA FLAG
CMP #1 ; IF FLAG SET THEN
BEQ RESET ; RESET IT
LDA #1 ; ELSE SET IT
STA FLAG
JMP SRCHLN ; CONTINUE SEARCH
RESET LDA #0 ; RESET THE FLAG TO ZERO
STA FLAG
JMP SRCHLN
ERROR LDA LINNUM ; RESTORE THE LINE NUMBER
TAX
LDA LINNUM+1
JSR LINPRT ; PRINT THE LINE NUMBER
JSR OUTSPC ; AND A SPACE
EXIT LDY #0 ; FIND THE NEXT LINE OF PROGRAM
LDA (STRLIN),Y
PHA
INY
LDA (STRLIN),Y
STA STRLIN+1
PLA
STA STRLIN
LDY #0
LDA (STRLIN),Y
CMP #0 ; IF A ZERO POSSIBLE END OF PROGRAM
BEQ EXITST
JMP NEWLIN
EXITST INY ; IF A ZERO THEN END OF PROGRAM
LDA (STRLIN),Y
CMP #0
BEQ DONE
JMP NEWLIN
DONE RTS
LSTOFF